Список работ

Отображатель массивов

Содержание

• Назначение отображателя массивов
• Отображение массивов
• Управление изображением
  • Команды меню View и Palette
  • Задание зоны вывода
  • Редактирование таблицы данных
  • Способ вывода изображения
• fagl-подпрограммы
• fav-подпрограммы
  • Введение
  • Действие fav-подпрограмм
• Распространение компонентов ОМ

Назначение отображателя массивов

Отображатель массивов (ОМ) фирмы Compaq® позволяет наблюдать как данные числовых массивов, так и их графическое представление. Отображатель содержит в качестве ядра графическую библиотеку OpenGL®, процедуры которой обеспечивают графический вывод. (Об употреблении OpenGL® в Фортране см., например, [1].) Дополнительно ОМ помогает манипулировать графическими данными, предоставляя возможности для перемещения, поворота и масштабирования изображения, а также для изменения способа его представления на экране. ОМ содержит:

• автономно запускаемое приложение, выполняющее отображение массивов;
• библиотеку Aview процедур, вызываемых из приложений Фортрана и предназначенных для управления ОМ;
• ActiveX®-процедуры библиотек Avis2D и AvisGrid;
• дополнительные визуальные средства.

Массив, переданный ОМ, отображается в двух видах:

1. в виде числовой таблицы, выводимой в верхней части окна ОМ;
2. в графическом виде как трехмерное изображение (3D-вид), или как цветовая карта, или как векторный граф, или как рисунок на плоскости.

Процедуры библиотеки Aview позволяют приложениям CVF или Visual C++ отображать (посредством OLE-автоматизации) данные массива, применяя ОМ. Также данные массива можно сохранить в виде файла, который загружается в ОМ в процессе его автономного использования. ActiveX®-процедуры (OCX) библиотек Avis2D и AvisGrid могут быть использованы любой поддерживающей автоматизацию средой, например Visual C++, Visual Basic® или CVF, для отображения массивов в разнообразных графических видах. Процедуры Avis2D обеспечивают при выполнении графического вывода более 100 свойств, методов и событий; процедуры AvisGrid применяются для создания представляющих массивы таблиц и предоставляют около 30 свойств, методов и событий. Возможны несколько вариантов употребления ОМ. Они, а также присущие им преимущества и недостатки перечислены в табл. 1.

Таблица 1. Варианты применения ОМ

Отображение массивов

Массивы отображаются на двумерной сетке (рис. 1, а).

Рис. 1. Отображение массива: а - двумерная сетка ОМ; б - растровая карта

При этом ОМ предоставляет следующие видовые режимы:

• 3D-вид, или Height Plot (приведен на рис. 1, а);
• растровая карта, или Image Map (построенному на рис. 1, а изображению соответствует приведенная на рис. 1, б карта);
• векторный граф, или Vector Graph (рассмотрен ниже);
• с, или Plane View (рассмотрен ниже).

Перечисленные режимы могут быть заданы как в ОМ непосредственно, так и в программе, из которой ОМ запускается. В ОМ переключение режима выполняется либо из меню (рис. 2, а), либо в результате выбора соответствующей иконки (рис. 2, б).

Рис. 2. Выбор видового режима: а - подпункты меню View;б - соответствующие им иконки

Рассмотрим пример употребления ОМ для вывода 3D-фигуры.
Пусть необходимо вывести параболоид, задаваемый уравнением

z = x² + y².

Создадим для этого двумерный массив bo, применив код

subroutine frame(bo, m, n)    ! Подпрограмма формирует массив bo,
implicit none    ! содержащий точки параболоида
integer(4) :: m, n
integer(4) :: i, j
real(4) :: bo(m, n), x, y
do j = 1, n    ! Формирование массива bo
do i = 1, m
! x- и y-координаты точки параболоида
x = float(i - m /2)
y = float(j - n /2)
bo(i, j) = x * x + y * y    ! bo(i, j) содержит z-координату точки параболоида
end do
end do
end subroutine frame

Отображение массива обеспечит программа

program para
use avdef
use avviewer
use dflib
implicit none    ! Данные о параболоиде z = x² + y²
! Протяженности массива bo по первому и второму измерениям
integer(4) :: m = 20, n = 20
real(4), allocatable :: bo(:, :)    ! Массив точек параболоида
!dec$attributes array_visualizer :: bo
integer(4) hv, status
character(1) :: key
allocate (bo(m, n))
call frame(bo, m, n)    ! Формирование параболоида
call faglStartWatch(bo, status)    ! Сообщаем ОМ имя отображаемого массива
print *, "Starting Array Viewer"
call favStartViewer(hv, status)    ! Создаем экземпляр ОМ
call favSetArray(hv, bo, status)    ! Отображаем массив bo
! Задаем имя, выводимое ОМ при отображении массива bo
call favSetArrayName(hv, "Paraboloid", status)
! Показываем ОМ на экране
call favShowWindow(hv, AV_TRUE, status)
print *, "Press any key to close down the viewer"
key = getcharqq( )
call favEndViewer(hv, status)    ! Закрываем ОМ
call faglEndWatch(bo, status)    ! Удаляем массив из списка наблюдения
deallocate(bo)
end program para    ! Результат приведен на рис. 3

Рис. 3. Параболоид подпрограммы frame

Сформированный подпрограммой frame массив содержит фрагмент параболоида, пересекаемого вертикальными плоскостями. Чтобы получить более целостную картину, сформируем параболоид, обратившись к подпрограмме frame2, которая возвращает приведенную на рис. 4 каркасную модель параболоида.

Рис. 4. Параболоид в виде граней: а – каркасная модель; б – угол разбиения

subroutine frame2(bo, nd, ch)    ! Подпрограмма формирует массив bo,
implicit none    ! содержащий точки параболоида
integer(4) :: nd, ch
integer(4) :: i, j, k
real(4) :: bo(4, nd * ch)
real(4) :: al, dal, dh, hp
real(4) :: hcover = 20.0    ! Высота параболоида
! Формируем массив bo, содержащий точки параболоида
dh = hcover / real(ch - 1)    ! Расстояние между сечениями
! dal – приращение угла разбиения al, используемое при переходе
! от одной точки разбиения сечения к другой (см. рис. 4, б)
dal = 4.0 * asin(1.0) / real(nd)    ! dal = 2π / n
hp = 0.0    ! Низ параболоида в начале координат
k = 0
do i = 1, ch    ! Формирование массива bo
al = 0.0    ! Начальный угол разбиения
do j = 1, nd
k = k + 1
! Используем параметрическое уравнение окружности
! x- и y-координаты точки параболоида
bo(1:2, k) = sqrt(hp) * (/ cos(al), -sin(al) /)
bo(3, k) = hp    ! z-координата
al = al + dal
end do
hp = hp + dh
end do
bo(4, :) = 0.0    ! Цвет вывода - самый темный
end subroutine frame2

Вызов frame2 выполним в программе para, заменив им вызов подпрограммы frame:

integer(4) :: nd = 24    ! Число разбиений одного сечения параболоида
integer(4) :: ch = 7    ! Число пересекающих параболоид плоскостей
. . .
allocate(bo(4, nd * ch))
call frame2(bo, nd, ch)

Переключившись после отображения массива в режим векторного графа и погасив вывод осей, получим приведенное на рис. 5 изображение.

Рис. 5. Параболоид из frame2 в режиме векторного графа

Фигура, нарисованная в режиме векторного графа, похожа на параболоид, но представляется только в виде точек. В 3D-режиме ОМ образ массива bo представляется рис. 6, а, плоский вид - рис. 6, б.

Рис. 6. Представление массива bo: а – 3D-режим; б – плоский вид

Иными словами, на этих рисунках мы наблюдаем закономерности изменения координат принадлежащих параболоиду точек, размещенных в массиве bo подпрограммой frame2.
Чтобы получить тонированное 3D-изображение параболоида, подобное приведенному на рис. 5, воспользуемся подпрограммой frame3, в которой точки рассчитываются таким же образом, как и в подпрограмме frame2, и размещаются в массиве botemp, а затем для каждой точки параболоида отыскивается соответствующие ей индексы в массиве bo формы (m, n). Эти индексы вычисляются из предположения, что нижняя точка параболоида имеет индексы m/2 и n/2.

subroutine frame3(bo, m, n, nd, ch)    ! Подпрограмма формирует массив bo,
implicit none    ! содержащий точки параболоида
integer(4) :: m, n, nd, ch
integer(4) :: i, j, k, ibo, jbo
real(4) :: bo(m, n), botemp(3, nd * ch)
! Максимальные значения координат параболоида
real(4):: xma, yma
real(4):: x, y, z, bomax
real(4) :: al, dal, dh, hp
real(4) :: hcover = 20.0    ! Высота параболоида
! Формируем массив botemp, содержащий координаты точек параболоида
dh = hcover / real(ch - 1)    ! Расстояние между сечениями
! dal - приращение угла разбиения al, используемое при переходе
! от одной точки разбиения сечения к другой (см. рис. 4, б)
dal = 4.0 * asin(1.0) / real(nd)    ! dal = 2π/n
hp = 1.0e-7 * hcover    ! Низ параболоида в начале координат
k = 0
do i = 1, ch    ! Формирование массива botemp
al = 0.0    ! Начальный угол разбиения
do j = 1, nd
k = k + 1
! Используем параметрическое уравнение окружности
! x- и y-координаты точки параболоида
botemp(1:2, k) = sqrt(hp) * (/ cos(al), -sin(al) /)
botemp(3, k) = hp    ! z-координата
al = al + dal
end do
hp = hp + dh
end do
bo = -1.0    ! Инициализация массива bo
xma = maxval(botemp(1, :));
yma = maxval(botemp(2, :))
do i = 1, k    ! Формируем теперь массив bo
x = botemp(1, i); y = botemp(2, i)
ibo = m / 2 * (1.0 + x / xma); jbo = n / 2 * (1.0 + y / yma)
ibo = min(m, ibo); ibo = max(1, ibo)
jbo = min(n, jbo); jbo = max(1, jbo)
z = botemp(3, i)
bo(ibo, jbo) = z
end do
! Не все элементы массива bo могут быть определены в предшествующем цикле
! Заменим каждый отрицательный элементы массива bo
! его наибольшим элементом
bomax = maxval(bo)
where(bo < 0.0) bo = bomax
end subroutine frame3

Вызов frame3 выполним в программе para, заменив им вызов подпрограммы frame:

integer(4) :: nd = 100    ! Число разбиений одного сечения параболоида
integer(4) :: ch = 50    ! Число пересекающих параболоид плоскостей
integer(4) :: m = 20, n = 20    ! Протяженности массива bo
. . .
allocate(bo(m, n))
call frame3(bo, m, n, nd, ch)    ! Результат приведен на рис. 7

Рис. 7. 3D-вид созданного в frame3 параболоида

Для всех видов графиков, кроме векторного, строка массива ассоциируется с осью x, столбец - с осью y. Значение соответствующего элемента массива - с осью z.

Управление изображением

Характер воспроизведения изображения можно изменять, работая непосредственно в ОМ. Для этой цели существуют команды, доступ к которым осуществляется через меню (рис. 8).

Рис. 8. Меню ОМ

Помимо реализуемых через меню возможностей в ОМ можно, применяя мышь, вращать изображение и выделять требуемый диапазон данных в содержащей их таблице (рис. 9).

Рис. 9. Таблица данных ОМ

Для вращения изображения достаточно разместить мышь на поле графического вывода, нажать правую кнопку мыши и затем, оставаясь на поле вывода, перемещать мышь в произвольном направлении (рис. 10).

Рис. 10. Три проекции параболоида

Многие предоставляемые ОМ возможности, доступ к которым осуществляется через пункты меню File, Edit или Help (рис. 11), традиционны и не требуют специальных пояснений.

Рис. 11. Пункты меню ОМ: а – File; б – Edit; в – Help

Доступ к иным операциям ОМ обеспечивают пункты меню View, Settings, Colors, Palette и Data (рис. 12).

Рис. 12. Пункты меню ОМ: а – View; б – Settings; в – Colors; г – Palette; д – Data

Действие некоторых подпунктов, например Toolbars или Status Bar из меню Settings, традиционно. Других - таких, как Background (цвет фона) из меню Colors или Gray Scale (оттенки серого цвета) из меню Palette,- понятно интуитивно. Некоторые возможности требуют пояснений, к изложению которых мы и переходим.

Команды меню View и Palette

Выбор подпункта Home View вернет повернутое изображение либо в заданное по умолчанию положение, либо в положение установленное в результате действия подпункта Set Home.
Те же результаты получатся при работе с иконками

Установить соответствие между точкой на поверхности и ячейкой таблицы данных позволяет маркер, который появится на изображении после выбора Show Marker. Когда маркер присутствует на рисунке, то каждый двойной удар мыши по ячейке таблицы вызовет его перемещение в соответствующую точку изображения, и наоборот, каждый двойной удар мыши по точке на фигуре вызовет, во-первых, перемещение в эту точку маркера и, во-вторых, выделение соответствующей ячейки данных (рис. 13).

Рис. 13. Маркер и таблица данных

Замечания:

1. Позиционирование мыши на точке поверхности приводит к появлению на рисунке следующей информации: координаты соответствующей ячейки в таблице данных и z-координаты точки поверхности (рис. 13). Появившиеся данные не связаны с отображаемым маркером.
2. Для работы с маркером в ОМ предусмотрена иконка
   

Выбор Show Palette приведет к появлению столбца, отображающего используемую палитру цветов, с указанием соответствия оттенок – z-координата объекта (рис. 14).

Рис. 14. Фигура и палитра

Вывод и удаление столбика с палитрой выполняется также кнопкой

Вид палитры выбирается в меню Palette из списка:

• Gray Scale (шкала оттенков серого цвета, в которой минимальному значению z-координаты соответствует черный цвет, а максимальному – белый);
• Gray Scale Banded (шкала оттенков серого цвета с границами);
• Gray Scale Inverted (инвертированная шкала оттенков серого цвета);
• Rainbow (шкала цветов радуги);
• Rainbow Banded (шкала цветов радуги с границами);
• Rainbow Inverted (инвертированная шкала цветов радуги.

По умолчанию используется система цветов RGB, в которой результирующий цвет определяется как смесь красного, зеленого и синего компонентов. После выбора в меню Palette пункта Edit появится окно (рис. 15), в котором можно перейти к системе цветов HSV (оттенок - насыщение - величина) и выполнить также иные операции по настройке палитры.

Рис. 15. Настройка палитры цветов

Задание зоны вывода

Зона вывода (ЗВ) - это отображаемый диапазон таблицы данных. По умолчанию отображается вся таблица (т. е. весь массив). Так, в рассматриваемом параболоиде протяженность каждого измерения равна 20, а нижняя граница - единице. ЗВ, однако, можно изменить, указав нижние границы и протяженности каждого измерения массива. Установим, к примеру, нижнюю границу каждого измерения, равной двум, а протяженность, равной пяти. Используем для этого приведенный на рис. 16 диалог, запускаемый в результате выполнения цепочки Settings – ROI.

Рис. 16. Задание зоны вывода

Нажатие OK приведет к изменению таблицы данных (рис. 17, ,а и изображения (рис. 17, б).

Рис. 17. Таблица данных и изображение после изменения зоны вывода

Далее, используя приведенный на рис. 18 навигатор, можно либо перемещаться по изображению, сохраняя заданный размер ЗВ, либо выполнять ее увеличение или уменьшение.

Рис. 18. Навигатор: а – просмотр изображения; б – изменение ЗВ

Кроме того, приведенное на рис. 16 окно, позволяет менять, используя радиокнопки Row и Col, порядок строк и столбцов (в массивах ранга 2 в случае Фортрана строки задаются первым измерением, а столбцы - вторым; в массивах СИ и Бейсика порядок задание строки и столбцов обратный) и задавать величину нижней границы (поле Lower Bound), устанавливая ее, например, равной значению, заданному в программе. По умолчанию нижняя граница каждого измерения равна единице.
Заметим, что в заданной ЗВ ограничить область вывода можно, выделив в таблице прямоугольник данных и нажав на левую кнопку из рис. 18, б.

Редактирование таблицы данных

Становится возможным после активизации пункта Cell Edit Enabled в приведенном на рис. 19 окне и нажатия кнопки OK.

Рис. 19. Способ вывода числовых данных

Окно появляется после выбора Settings – Data View. Собственно редактирование данных становится возможным после двойного щелчка мышью по клетке таблицы данных. Ввод новых данных и нажатие на Enter вызовет перестройку изображения.
Другие возможности окна следуют из имеющихся на нем надписей.

Способ вывода изображения

Задается в окне Settings - Graph (рис. 20).

Рис. 20. Способ вывода изображения

Установленная по умолчанию конфигурация (приведена на рис. 20) предусматривает в режиме 3D-вида вывод поверхности (Surface):

• с плавным переходом (интерполяцией) цветов (Float Shading);
• с бликами (Highlighting), проявляющимися при вращении объекта;
• со сглаженными линиями (Smooth Lines).

При этом показывается сетка (Show Grid), удаляются невидимые линии (Hidden Line) и используется цветовая палитра (Use Palette). Манипуляция имеющимися на окне кнопками приведет к изменению способа вывода изображения. Так, выбор Wireframe вызовет переход к каркасной модели, а Barchart – к диаграмме (рис. 21).

Рис. 21. Часть параболоида: а – тонированная поверхность;б – каркасная модель; в – диаграмма

Активизация Texture On вызовет наложение на объект текстуры, а – Depthcue приведет к изменению способа достижения эффекта глубины – снижается контрастность более глубоких участков фигуры (рис. 22).

Рис. 22. Эффект глубины: а – режим Depthcue отключен;б – режим Depthcue включен

Перейдем теперь к описанию поставляемых с ОМ процедур, встраивание которых в приложение позволяет запускать ОМ, передавать ему массив, управлять изображением, выполняя при необходимости пересчет отображаемых данных и обновление отвечающей им фигуры.

fagl-подпрограммы

Вызов и некоторые функции управления ОМ обеспечивают приведенные в табл. 2 fagl-подпрограммы. Параметры подпрограмм содержатся в табл. 3.

Таблица 2. Fagl-подпрограммы ОМ

Таблица 3. Параметры fagl-подпрограмм

Для вызова приведенных в табл. 2 подпрограмм в использующем их программном компоненте следует выполнить ссылку

use avdef    ! Ссылка на ...ArrayVisualizer\include\avdef.f90

Модуль AVDEF содержит интерфейсы fagl-подпрограмм. Перечисленные подпрограммы обычно используются следующим образом:

• до отображения массива array вызовите faglStartWatch, с параметром array;
• если необходимо отображать массив, имея нижнюю левую границу, отличную от единицы, примените faglLBound;
• для отображения сообщения, сопровождающего выводимые данные, вызовите faglName;
• для запуска ОМ и отображения массива array вызовите faglShow с первым параметром, равным array. ОМ будет функционировать до тех пор, пока не выполнена команда faglClose;
• если хранимые массивом данные подверглись изменениям, то для их отображения вызовите faglUpdate;
• для сохранения массива array в виде файла с расширением AGL (Array Graphing Language) вызовите faglSaveAsFile, использовав array в качестве первого параметра. При этом ОМ может быть неактивным;
• при необходимости можно вызвать faglGetShareName и получить строку filename, позволяющую процедурам Avis2D и AvisGrid осуществлять доступ к области памяти, занятую массивом;
• после завершения просмотра массива вызовите faglEndWatch.

Дополнительно для выполнения действий, обычно производимых интерактивно, можно применять fav-процедуры.

Пример. Выводится в режиме векторного графа график функции y = xsinx на отрезке [-6, 6], а вслед после некоторой задержки – график y = sqrt(|xsinx|). Обновление изображения выполняет подпрограмма faglUpdate.

program sinx use avdef
use avviewer
use dflib
implicit none
integer(4) :: n = 50    ! Число разбиений отрезка
real(4), allocatable :: fun(:, :)    ! Массив значений функции y = xsinx
!dec$attributes array_visualizer :: fun
real(4) :: a = -6.0, b = 6.0, x, dx
integer(4) i, hv, status, nError
character(1) :: key
allocate(fun(2, n))
dx = (b - a) / float(n)    ! Шаг изменения x
x = a
do i = 1, n    ! Формирование массива данных
fun(1, i) = x
fun(2, i) = x * sin(x)
x = x + dx
end do
call faglStartWatch(fun, status)    ! Сообщаем ОМ имя отображаемого массива
print *, "Starting Array Viewer"
! Запуск ОМ с использованием fav-подпрограммы
call favStartViewer(hv, status)
if(status /= 0) then
call favGetErrorNo(hv, nError, status)
if(nError /= 0) then
print *, "Array Viewer reports error ", nError
stop
end if
end if
! Передаем ОМ данные подлежащего отображению массива
call favSetArray(hv, fun, status)
! Задаем заголовок
call favSetArrayName(hv, "y = x * sin(x)", status)
! Задаем отображение массива в виде векторного графа
call favSetGraphType(hv, VectorGraph, status)
! Показываем ОМ на экране
call favShowWindow(hv, av_true, status)
call sleepqq(5000)    ! Задержка в 5000 миллисекунд
! Задаем новый заголовок
call favSetArrayName(hv, "y = sqrt(abs(x * sin(x)))", status)
fun(2, :) = sqrt(abs(fun(2, :)))    ! Вносим изменения в массив
call favUpdate(hv, 0, status)    ! и отображаем их на графике
print *, "Press any key to close down the viewer"
key = getcharqq( )
call favEndViewer(hv, status)    ! Закрываем ОМ
call faglEndWatch(fun, status)    ! Освобождаем ресурсы
deallocate(fun)
end program sinx    ! Результаты приведены на рис. 23

Рис. 23. Два векторных графа: а - y = xsinx; б - y = sqrt(|xsinx|)

В этом и более ранних примерах употреблен DEC-атрибут ARRAY_VISUALIZER:

real(4), allocatable :: MyArray(:, :)
!dec$attributes array_visualizer :: MyArray

Его действие таково: память, занимаемая массивом Myarray, используется и ОМ, и приложением. При отсутствии атрибута будут созданы две области для данных Myarray и при каждом обновлении массива после вызова faglUpdate данные будут копироваться из области, принадлежащей приложению, в область, используемую ОМ.
Заметим, что DEC-атрибут ARRAY_VISUALIZER может быть применен только с динамическими объектами, т. е. объектами, обладающими атрибутом POINTER или ALLOCATABLE.

fav-подпрограммы

Введение

Fav-подпрограммы управляют ОМ и обеспечивают взаимодействие ОМ с приложением. Как правило, fav- и fagl-подпрограммы употребляются совместно. Fav-подпрограммы подразделяются на группы, имеющие названия:

• запуск ОМ;
• доступ к данным;
• зона вывода;
• фильтрация данных;
• палитра;
• оси координат;
• выбор;
• виды изображений;
• 3D-вид;
• растровая карта;
• векторный граф;
• отображение данных;
• камера;
• маркер;
• разное.

Работа с fav-подпрограммами станет возможной после выполнения ссылки

use avviewer

в которой модуль AVVIEWER содержит интерфейсы и константы подпрограмм.

Действие fav-подпрограмм

Вызываемые fav-подпрограммами действия приведены в табл. 4. Описание выполнено в соответствии с перечисленными выше группами.

Таблица 4. Fav-подпрограммы

Замечание. Подпрограмма favGet*, если соответствующая favSet*-подпрограмма не вызывалась, вернет заданное по умолчанию значение, опрос которого favGet* выполняет. В комплекте поставки ОМ имеются примеры его употребления. Они расположены в директории ...\ArrayVisualizer\Samples\Fortran\. Описание примеров можно просмотреть в Web-браузере, загрузив ...\ArrayVisualizer\Samples\Samples.htm.

Пример. Выводится 3D-вид параболоида, создаваемый подпрограммой frame3. При этом:

• изменяются имена осей координат: dim1 - на x, а dim2 - на y (команда favSetAxisLabel);
• задается отличная от установленной по умолчанию позиция камеры, равная (-2.3, -2.3, 2.0) (команда favSetCameraPosition), и позиция точки наблюдения - (0.0, 0.5, 0.0) (команда favSetCameraCoi);
• число больших разметок на каждой из осей устанавливается равным трем, а маленьких - единице (команды favSetNumMajorTickmarks и favSetNumMinorTickmarks);
• при выводе изображения применяются оттенки серого цвета (команда favSetPaletteId).

program para2
use avdef
use avviewer
use dflib
implicit none    ! Данные о параболоиде z = x² + y²
! Протяженности массива bo по первому и второму измерениям
integer(4) :: m = 20, n = 20
integer(4) :: nd = 100    ! Число разбиений одного сечения параболоида
integer(4) :: ch = 50    ! Число пересекающих параболоид плоскостей
real(4), allocatable :: bo(:, :)    ! Массив точек параболоида
!dec$attributes array_visualizer :: bo
integer(4) hv, status
character(1) :: key
character(av_max_label_len) :: xLabel = 'x', yLabel = 'y'
allocate (bo(m, n))
call frame3(bo, m, n, nd, ch)    ! Формирование параболоида
call faglStartWatch(bo, status)    ! Сообщаем ОМ имя отображаемого массива
print *, "Starting Array Viewer"
call favStartViewer(hv, status)    ! Создаем экземпляр ОМ
call favSetArray(hv, bo, status)    ! Отображаем массив bo
! Задаем имя, выводимое ОМ при отображении массива bo
call favSetArrayName(hv, "Paraboloid", status)
! Задаем режим вывода заданных пользователем имен осей координат
call favSetUseAxisLabel(hv, x_axis, 1, status)
call favSetUseAxisLabel(hv, y_axis, 1, status)
! Новые имена x- и y-осей координат. Длина переменных, задающих имена осей,
! равна AV_MAX_LABEL_LEN
call favSetAxisLabel(hv, x_axis, xLabel, status)
call favSetAxisLabel(hv, y_axis, yLabel, status)
! Позиция точки наблюдения
call favSetCameraCoi(hv, 0.0, 0.5, 0.0, status)
! Позиция камеры
call favSetCameraPosition(hv, -2.3, -2.3, 2.0, status)
! Устанавливаем режим явного задания разметок координатных осей
call favSetAxisAutoDetail(hv, 0, status)
! Число больших разметок на координатных осях
call favSetNumMajorTickmarks(hv, x_axis, 3, status)
call favSetNumMajorTickmarks(hv, y_axis, 3, status)
call favSetNumMajorTickmarks(hv, z_axis, 3, status)
! Число малых разметок на координатных осях
call favSetNumMinorTickmarks(hv, x_axis, 1, status)
call favSetNumMinorTickmarks(hv, y_axis, 1, status)
call favSetNumMinorTickmarks(hv, z_axis, 1, status)
! Задание палитры из оттенков серого цвета
call favSetPaletteId(hv, greyscale, status)
! Показываем ОМ на экране
call favShowWindow(hv, AV_TRUE, status)
print *, "Press any key to close down the viewer"
key = getcharqq( )
call favEndViewer(hv, status)    ! Закрываем ОМ
call faglEndWatch(bo, status)    ! Удаляем массив из списка наблюдения
deallocate(bo)
end program para2    ! Результат приведен на рис. 24

Рис. 24. Параболоид из программы para2

Распространение компонентов ОМ

Библиотека Aviewxxx.DLL (Aview110.DLL для версии 1.1 ОМ) должна поставляться с приложением, использующим процедуры ОМ. Причем DLL должна находиться в той же директории, что и приложение, либо приложению должен быть известен путь к DLL.
Если приложение использует Avis2D- и/или AvisGrid-процедуру, перенесите Avis2D.ocx- и/или AvisGrid.ocx-файл на компьютер, где будет запускаться приложение, и зарегистрируйте процедуры, выполнив команду

regsvr32 Avis2D.ocx

и/или команду

regsvr32 AvisGrid.ocxs

Список работ